Скрипты рисунков на MetaPost
[Download]
mp_16.html

       
 1    % !TeX encoding = UTF-8 Unicode
 2    % !TeX program = lualatex

 4    % MSP, 23.07.20, 15:50

 6    % FILE: pict_z16_v16_2020.tex

 8    % TASK
 9    %   Четырёхугольник ABCD вписан в окружность, причём сторона CD --
 10   %   диаметр этой окружности. Продолжение перпендикуляра AH к диагонали
 11   %   BD пересекает сторону CD в точке E, а окружность -- в точке F,
 12   %   причём H -- середина AE.

 14   %   a) Докажите, что четырёхугольник BCFE -- параллелограмм.
 15   %   б) Найдите площадь четырёхугольника ABCD, если известно, что
 16   %      AB = 6 и AH = 2 sqrt 5.

 18   % Compilator: LuaLaTex
 19   % Font Encoding: utf-8
 20   % Cod picture: luamplib & mplibcode

 22   % MSP, 23.10.17, 19:08
 23   % NOTE. LuaLaTeX обрабатывает файлы только в кодировке UTF-8
 24   %       В настройках редактора выберите UTF-8

 26   \documentclass [border = 5mm] {standalone}

 28   \usepackage {luamplib}
 29   \begin {document}
 30     \begin {mplibcode}

 32       % чтобы шрифт записывался прямо в Post-script-cod картинки
 33       prologues := 3;

 35       % загрузим библиотеку макросов
 36       input macros_msp;

 38       % 256 цветов
 39       input mpcolornames;

 41       % рисунок N 1
 42       beginfig (1);

 44         % расстояние отступа для меток (label)
 45         labeloffset := 6bp;

 47         % Шрифт
 48         defaultfont := "phvr8r";

 50         % увеличение шрифта
 51         defaultscale := 1.2;
 52         %defaultscale := 12pt / fontsize defaultfont;

 54         % толщина пера
 55         pickup pencircle scaled 1bp;

 57         % масштаб
 58         u := .5cm;

 60         color lblue;
 61         lblue := DeepSkyBlue3;

 63         %color lgreen;
 64         %lgreen := OliveDrab3;

 66         % точки задачи
 67         pair A, B, C, D, H, E, F, O;

 69         E := (8u, 0);
 70         %draw_point (E)(black)(4bp);
 71         %label.bot ("E", E);

 73         A := (12u, 6u);
 74         draw_point (A)(black)(4bp);
 75         label.urt ("A", A);

 77         % EH = HA
 78         H := 1/2 [E, A];
 79         %draw_point (H)(black)(4bp);
 80         %label.lft ("H", H);

 82         % для определения прямой E--z1
 83         z1 = (18u, 0);
 84         %draw_point (z1)(black)(4bp);
 85         %label.bot ("z1", z1);

 87         D = whatever [E, z1];
 88         % EA _|_ HD
 89         (E-A) dotprod (H-D) = 0;
 90         draw_point (D)(black)(4bp);
 91         label.rt ("D", D);

 93         % [EA], [HD]
 94         %draw E--A;
 95         draw H--D;

 97         % circle
 98         % O
 99         % если восставить перпендикуляр к середине [AD],
 100        %   то он пересечёт (ED) в центре окружности, проходящей
 101        %      через A и D.
 102        z2 = 1/2 [A, D];
 103        %draw_point (z2)(black)(4bp);
 104        %label.bot ("z2", z2);
 105        %draw A--D;
 106        O = whatever [E, D];
 107        % z2--O _|_ [AD]
 108        (A - D) dotprod (z2 - O) = 0;
 109        %draw_point (O)(black)(4bp);
 110        %label.bot ("O", O);

 112        % C
 113        C = D rotatedaround (O, -180);
 114        %draw_point (C)(black)(4bp);
 115        %label.bot ("C", C);

 117        % окружность
 118        path p;
 119        p := circle (O, abs (O-D));
 120        draw p;

 122        % z3 на (HD)
 123        % пути прописываем в одном направлении
 124        H - z3 = 5cm * dir (angle (D - H));
 125        %draw_point (z3)(black)(5bp);
 126        %label.top ("z3", z3);

 128        % B
 129        path q;
 130        q := H--z3;
 131        B = q intersectionpoint p;
 132        %draw_point (B)(black)(4bp);
 133        %label.top ("B", B);

 135        % [DB]
 136        draw D--B;

 138        % угол DHA - прямой
 139        mark_right_angle (D, H, A, 6bp);

 141        % AH = HE
 142        draw_marked (A--H)(1)(lblue);
 143        draw_marked (H--E)(1)(lblue);
 144        draw A--H withcolor lblue;
 145        draw E--H withcolor lblue;
 146        draw_point (H)(lblue)(4bp);
 147        label.lft ("H", (xpart H - 2bp, ypart H - 2bp));

 149        % [CD]
 150        %draw C--D;

 152        % F
 153        E - z4 = 6cm * dir (angle (A-E));
 154        %draw_point (z4)(black)(5bp);
 155        %label.top ("z4", z4);

 157        q := z4--E;
 158        F = q intersectionpoint p;
 159        %draw_point (F)(black)(4bp);
 160        %label.top ("F", F);

 162        % [EF]
 163        draw E--F;

 165        % ABCD
 166        draw A--B--C--D--A;

 168        % BCFE
 169        draw B--C--F--E--B withcolor red;

 171        draw_point (B)(red)(4bp);
 172        label.top ("B", B);

 174        draw_point (C)(red)(4bp);
 175        label.lft ("C", C);

 177        draw_point (F)(red)(4bp);
 178        label.bot ("F", F);

 180        draw_point (E)(red)(4bp);
 181        label.lrt ("E", E);

 183        draw_point (O)(blue + red)(6bp);
 184        label.bot ("O", O);

 186      endfig;

 188      bye.

 190    \end {mplibcode}
 191  \end {document}



     
Web-листинг с сайта http://www.Best-Listing.ru
Автор решения: Сергей Митрофанов Кто подготовил код к публикации: Sergey Mitrofanov
Дата записи в базу данных: 01-08-2020 Время записи в базу данных: 16:13:58
Просмотров: 6 Download: 1
mp_16.html
[Download]

Скрипты рисунков на MetaPost
Valid XHTML 1.0 Transitional Valid CSS

Copyright © www.Best-Listing.ru, 2006–2021