% !TeX encoding = UTF-8 Unicode
         % !TeX program = lualatex

         % MSP, 25.07.20, 14:00

         % FILE: pict_z16_v24_2020.tex

         % TASK
         %   В треугольнике ABC известно, что /_ BAC = 60o, /_ ABC = 45o.
         %   Продолжения высот треугольника ABC пересекают описанную около
         %   него окружность в точках M, N, P.

         %   Докажите, что треугольник MNP прямоугольный.
         %   Найдите площадь треугольника MNP, если известно, что BC = 10.

         % Compilator: LuaLaTex
         % Font Encoding: utf-8
         % Cod picture: luamplib & mplibcode

         % MSP, 23.10.17, 19:08
         % NOTE. LuaLaTeX обрабатывает файлы только в кодировке UTF-8
         %       В настройках редактора выберите UTF-8

         % titlepage - отмена нумерации 1-ой страницы
         \documentclass [border = 5mm] {standalone}

         \usepackage {luamplib}
         \begin {document}
           \begin {mplibcode}

             % чтобы шрифт записывался прямо в Post-script-cod картинки
             prologues := 3;

             % загрузим библиотеку макросов
             input macros_msp;

             % 256 цветов
             input mpcolornames;

             % рисунок N 1
             beginfig (1);

               % расстояние отступа для меток (label)
               labeloffset := 7bp;

               % Шрифт
               defaultfont := "phvr8r";

               % увеличение шрифта
               defaultscale := 1.2;
               %defaultscale := 12pt / fontsize defaultfont;

               % толщина пера
               pickup pencircle scaled 1bp;

               % масштаб
               u := 6mm;

               color lblue;
               lblue := DeepSkyBlue3;

               %color lgreen;
               %lgreen := OliveDrab3;

               % точки рисунка
               pair A, B, C, M, N, P;

               % A
               A := origin;
               %draw_point (A)(black)(4bp);
               %label.lft ("A", A);

               % C
               C := (8u, 0);
               %draw_point (C)(black)(4bp);
               %label.rt ("C", C);

               % hidden z1
               z1 = C rotatedaround (A, 60);
               %draw_point (z1)(black)(4bp);
               %label.lft ("z1", z1);

               % hidden z2
               z2 = A rotatedaround (C, -75);
               %draw_point (z2)(black)(4bp);
               %label.lft ("z2", z2);

               % B
               B = whatever [A, z1];
               B = whatever [C, z2];
               draw_point (B)(black)(4bp);
               label.top ("B", B);

               % ABC
               draw A--B--C--A;

               % < BAC
               mark_circle_angle (C, A, B)(1)(6bp);

               % < ABC
               mark_circle_angle (A, B, C)(2)(6bp);

               % окружность
               path o;
               o := opis_circle (A, B, C);
               draw o;

               pair hA, hB, hC;
               path p;

               % M
               hA := osn_perpend (A, B, C);

               % z3 - далёкая скрытая точка за описанной окружностью
               A - z3 = 8cm * dir (angle (A-hA));
               p := hA--z3;

               M = p intersectionpoint o;
               %draw_point (M)(black)(4bp);
               %label.rt ("M", M);

               draw A--M;
               mark_right_angle (A, hA, C)(5bp);

               % N
               hB := osn_perpend (B, A, C);

               % z3 - далёкая скрытая точка за описанной окружностью
               B - z4 = 8cm * dir (angle (B - hB));
               p := hB--z4;

               N = p intersectionpoint o;
               %draw_point (N)(black)(4bp);
               %label.bot ("N", N);

               draw B--N;
               mark_right_angle (B, hB, A)(5bp);

               % P
               hC := osn_perpend (C, A, B);

               % z5 - далёкая скрытая точка за описанной окружностью
               C - z5 = 8cm * dir (angle (C - hC));
               p := hC--z5;

               P = p intersectionpoint o;
               %draw_point (P)(black)(4bp);
               %label.lft ("P", P);

               draw C--P;
               mark_right_angle (A, hC, C)(5bp);

               % что доказать - красным, MNP
               draw o withcolor lblue;
               draw M--N--P--M withcolor red;

               draw_point (M)(red)(5bp);
               label.rt ("M", M);

               draw_point (N)(red)(5bp);
               label.bot ("N", N);

               draw_point (P)(red)(5bp);
               label.lft ("P", P);

               draw_point (A)(black)(5bp);
               label.lft ("A", A);

               draw_point (C)(black)(5bp);
               label.rt ("C", C);

               draw_point (B)(black)(5bp);
               label.top ("B", B);

             endfig;

             bye.

           \end {mplibcode}
         \end {document}