% !TeX encoding = UTF-8 Unicode
% !TeX program = lualatex
% MSP, 22.07.20, 15:30
% FILE: pict_z16_v13_2020.tex
% TASK
% Окружность с центром в точке O пересекает каждую из сторон
% трапеции ABCD в двух точках.
% Четыре получившиеся хорды окружности равны.
% а) Докажите, что биссектрисы всех углов трапеции пересекаются
% в одной точке.
% б) Найдите высоту трапеции, если окружность пересекает боковую
% сторону AB в точках K и L так, что AK = 19, KL =12, LB = 3.
% Compilator: LuaLaTex
% Font Encoding: utf-8
% Cod picture: luamplib & mplibcode
% MSP, 23.10.17, 19:08
% NOTE. LuaLaTeX обрабатывает файлы только в кодировке UTF-8
% В настройках редактора выберите UTF-8
\documentclass [border = 5mm] {standalone}
\usepackage {luamplib}
\begin {document}
\begin {mplibcode}
% чтобы шрифт записывался прямо в Post-script-cod картинки
prologues := 3;
% загрузим библиотеку макросов
input macros_msp;
% 256 цветов
input mpcolornames;
def otr (expr E, F)(text color) =
draw_marked (E--F, 1)(color);
draw E--F withcolor color;
draw_point (E)(color)(5bp);
draw_point (F)(color)(5bp);
enddef;
% рисунок N 1
beginfig (1);
% расстояние отступа для меток (label)
labeloffset := 6bp;
% Шрифт
defaultfont := "phvr8r";
% увеличение шрифта
defaultscale := 1.2;
%defaultscale := 12pt / fontsize defaultfont;
% толщина пера
pickup pencircle scaled 1bp;
% масштаб
u := .5cm;
color lblue;
lblue := DeepSkyBlue3;
%color lgreen;
%lgreen := OliveDrab3;
% точки задачи
pair O, A, B, C, D, K, L, S, T, E, F, P, Q;
S := origin;
T := (8u, 0);
E := (0, 12u);
F := (8u, 12u);
path opis;
opis := opis_circle (S, E, T);
draw opis;
draw_point (S)(lblue)(5bp);
label.bot ("S", S);
draw_point (T)(lblue)(5bp);
label.bot ("T", T);
% [ST]
%draw S--T;
draw_point (E)(lblue)(5bp);
label.top ("E", E);
% центр описанной окружности вокруг SET
%O - 1/2 [T, E] = whatever * (T-E) rotated 90;
%O - 1/2 [S, T] = whatever * (S-T) rotated 90;
O = center_opis_circle (S, E, T);
draw_point (O)(blue+red)(5bp);
label.bot ("O", O);
draw_point (F)(lblue)(5bp);
label.top ("F", F);
% LK == EF
L = F rotatedaround (O, 85);
draw_point (L)(lblue)(5bp);
label.lft ("L", L);
K = E rotatedaround (O, 85);
draw_point (K)(lblue)(5bp);
label.lft ("K", K);
% PQ = EF
Q = F rotatedaround (O, -105);
draw_point (Q)(lblue)(5bp);
label.rt ("Q", Q);
P = E rotatedaround (O, -105);
draw_point (P)(lblue)(5bp);
label.rt ("P", P);
% A
A = whatever [S, T];
A = whatever [L, K];
draw_point (A)(black)(5bp);
label.llft ("A", A);
% B
B = whatever [K, L];
B = whatever [E, F];
draw_point (B)(black)(5bp);
label.lft ("B", B);
% C
C = whatever [E, F];
C = whatever [P, Q];
draw_point (C)(black)(5bp);
label.rt ("C", C);
% D
D = whatever [S, T];
D = whatever [P, Q];
draw_point (D)(black)(5bp);
label.lrt ("D", D);
draw A--B--C--D--A;
% [EF] = [LK] = [ST] = [PQ]
otr (E, F)(lblue);
otr (L, K)(lblue);
otr (S, T)(lblue);
otr (P, Q)(lblue);
% если строчки раскомментируете, то увидите, что все
% 4-е биссектрисы пересекаются в одной точке O
%z1 = bisector (A, B, D);
%draw_point (z1)(red)(5bp);
%label.rt ("z1", z1);
%draw A--z1;
%z2 = bisector (B, A, C);
%draw_point (z2)(lblue)(5bp);
%label.rt ("z2", z2);
%draw B--z2;
%z3 = bisector (C, B, D);
%draw_point (z3)(lgreen)(5bp);
%label.rt ("z3", z3);
%draw C--z3;
%z4 = bisector (D, A, C);
%draw_point (z4)(blue)(5bp);
%label.rt ("z3", z3);
%draw D--z4;
%draw B--D withcolor red;
%draw C--A withcolor lgreen;
endfig;
bye.
\end {mplibcode}
\end {document}
|